1セクタゲーム作成に挑戦-3

;マップデータ作成
ld hl,0
ld de,map
maps2: call sltrd
cp 40
jr nc,mapsp ;空白設定
;障害物設定
call sltrd
and 00011111b ;a=ループキャラクタ数
ex de,hl ;hl=マップアドレス de=読み込みアドレス
ld (hl),1 ;緩衝キャラクタ
inc hl
maps1: or a
jr z,maps0 ;障害物
dec a
ld (hl),9 ;ループキャラクタ
inc hl
jr maps1
mapsp: call sltrd
and 00011111b
ex de,hl
mapsp0: ld (hl),0
inc hl
or a
jr z,maps3
dec a
jr mapsp0

maps0: ld (hl),11h ;障害物
inc hl
maps3: ex de,hl ;hl=読み込みアドレス, de=マップアドレス
push hl
ld hl,1fffh
or a
sbc hl,de
pop hl
jr nc,maps2

ld hl,1000h
ld (scpoint),hl
xor a
ld (dotpoint),a

ld b,255
ml1: push bc

ld de,(scpoint)
ld a,(dotpoint)
ld c,a
ld b,8
ml0: push bc
push de
call putsc
pop de
pop bc
inc c
djnz ml0
ld de,(scpoint)
inc de
ld (scpoint),de
pop bc
djnz ml1
ret

putsc: ;画面表示
;de=スクロールアドレス
;c=ドットポイント
ld a,24
ld (putsc1+1),a

ld hl,1800h
putsc2: ld b,32
putsc0: ld a,(de)
or a
jr z,putsc3
add a,c
putsc3: callbios wrtvrm
inc hl
inc de
djnz putsc0

ex de,hl ;hl=スクロールアドレス
push de
ld de,1000h
or a
sbc hl,de
ld a,00011111b
and h
ld h,a
add hl,de
pop de
ex de,hl

putsc1: ld a,0
dec a
ld (putsc1+1),a
jr nz,putsc2
ret

sltrd: ;スロット読み込み
ld a,(exptbl)
push de
call rdslt
pop de
inc hl
ret

scpoint: dw 0
dotpoint: db 0

map: equ 1000h